* Графические примитивы.
* Используются англоязычные слова для написания команд.
* Программа КОНЦЕПТ, 29.09.2009, www.gendoc.ru

english
input men1 выбор 'Сделайте выбор' 'цвета;типы линий;типы кистей;типы текста;треугольник;округлый прямоугольник;текст в прямоугольнике;домик;автомобиль'

* Функции графических объектов

function линия x1 y1 x2 y2 цвет толщина стиль
  set $LineColor [цвет]
  set $LineWidth [толщина]
  set $LineStyle [стиль]
  draw line [x1] [y1] [x2] [y2] 
return

function прямоугольник x1 y1 x2 y2 цвет толщина стиль заливка стиль_заливки 
  set $LineColor  [цвет]
  set $LineWidth  [толщина]
  set $LineStyle  [стиль]
  set $BrushColor [заливка]
  set $BrushStyle [стиль_заливки]
  draw box [x1] [y1] [x2] [y2] 
return

* Рисование домика
if [выбор] == домик
  set $LineWidth 5
  draw box  100 100 300 300
  draw line 200 50 100 100  
  draw line 200 50 300 100
  draw text 120 200 'Это домик'
end

* Рисование автомобиля
if [выбор] == автомобиль
  set $TextSize 30
  draw box    300 250 500 350
  draw box    150 350 650 450
  draw circle 200 400 300 500
  draw circle 500 400 600 500
  draw text   120 200 'Это автомобиль'
end

* Цвета
if [выбор] == цвета
  draw text 3 3 "Цвета:" 
  for 1;2;3;4;5;6;7;8;9;10;11;12;13;14;15;16
    expr * y [$LoopObj] 20
    inc y 20
    draw set 20 [y]
    set $BrushStyle 2
    draw text 0 0 "Цвет = [$LoopObj]" 
    прямоугольник 70 0 300 10 [$LoopObj] 1 1 [$LoopObj] 1
  next
end

* Типы линий
if [выбор] == 'типы линий'
  draw text 3 3 "Типы линий:" 
  for 1;2;3;4;5;6;7
    expr * y [$LoopObj] 20
    inc y 20
    draw set 20 [y]
    draw text 0 -6 "Стиль = [$LoopObj]" 
    линия 70 0 300 0 13 1 [$LoopObj]
  next
end

* Типы кистей
if [выбор] == 'типы кистей'
  draw text 3 3 "Типы кистей:" 
  for 1;2;3;4;5;6;7;8
    expr * y [$LoopObj] 30
    inc y 30
    draw set 30 [y]
    set $BrushStyle 2
    draw text 0 0 "Стиль = [$LoopObj]" 
    прямоугольник 70 0 300 20 13 1 1 13 [$LoopObj]
  next
end 
* Типы текста
if [выбор] == 'типы текста'
  set $BrushStyle 2
  draw text 3 3 "Типы текста:" 
  for 0;1;2;3;4
    expr * y [$LoopObj] 30
    inc y 20
    draw set 20 [y]
    set $TextStyle [$LoopObj]
    draw text 0 0 "Тип текста = [$LoopObj]" 
  next
end

set $LineColor  13
set $LineWidth  1
set $LineStyle  3
set $BrushStyle 5
set $BrushColor 14

* Треугольник
if [выбор] == треугольник
  draw triangle 10 10 200 50 100 200 
end

* Округлый прямоугольник
if [выбор] == 'округлый прямоугольник'
  draw roundrect 10 10 400 200 50 50 
end

* Текст в прямоугольнике
if [выбор] == 'текст в прямоугольнике'
  draw box 10 10 400 200
  draw textinbox 10 10 400 200 'Этот текст в центре прямоугольника'
end